marchのBLOG

>【日本語対応メッセージボード Japanese-MessageBoard v05】
のソースです。

以下は子プリムのスクリプトです。
見所は、getTextureUuid 関数の中にあるテクスチャのUUIDです。
16*16の文字が並んでいるテクスチャのUUIDです。
私の技術不足で、拡大するとガタガタが目立ちますが、
Secondlife内で自由に漢字を表示したい場合には役立つと思います。

これを作るためにGIMP2でBMPから透過tgaに変換するために
Script-Fuに手を出してみたものの時間切れになり、
結局はキー操作を記録再生するプログラムを使ったという思い出があります(^_^;)。

では、子プリムのスクリプトです。
ライセンスは、親プリムのスクリプトと一緒です。

//

//v03:5face.

//v04:comment_out llOwnerSay at init()

//v05:transparent_texture.,,

//

integer PANEL_ID = -1;

integer PRIM_PER_CHARACTOR = 5;        //1prim-5face

integer INPRIM_LEFT_LEFT    = 0;

integer INPRIM_LEFT_CENTER    = 1;

integer INPRIM_CENTER        = 2;

integer INPRIM_RIGHT_CENTER    = 3;

integer INPRIM_RIGHT_RIGHT    = 4;

key BLANK_TEXTURE = "5748decc-f629-461c-9a36-a35a221fe21f";         //blank image (100% white image with no alpha)

//key TRANSPARENT_TEXTURE = "f54a0c32-3cd1-d49a-5b4f-7b792bebc204";     //a 100% alpha (fully transparent) texture

vector FAIL_MAPPING_VECTOR = <-1.0, -1.0, -1.0>;        //use when mapping fail.



integer xmax = 16;

integer ymax = 16;



integer isDebugMode = FALSE;





integer getPanelId()

{

    string originalObjectDesc;

    integer originalObjectDescLen;

    integer resultId = -1;

    integer timeupCounter = 0;

    string tmpStr;

    string tmpSubStr;

    //

    originalObjectDesc = llGetObjectDesc();

    originalObjectDescLen = llStringLength(originalObjectDesc);

    //llOwnerSay("getPanelId" + ": original ObjectDesc length = " + (string)originalObjectDescLen + ".");

    if(originalObjectDescLen > 120)    // MAX(127 charactor) - 6 - 1;    //ID = 6 DIGITS.

    {

        llOwnerSay("getPanelId" + ": original ObjectDesc too long(" + (string)originalObjectDescLen + ")");

        return -1;

    }

    //

    llMessageLinked(LINK_THIS , 0, "getPanelId", NULL_KEY);

    do

    {

        tmpStr = llGetObjectDesc();

        tmpSubStr = llGetSubString(tmpStr, originalObjectDescLen, llStringLength(tmpStr));

        if(llStringLength(tmpSubStr) > 0)

        {

            // check first character of gotten ID is Numeric?

            if(llSubStringIndex("0123456789", llGetSubString(tmpSubStr, 0, 0)) >= 0)             

            {

                resultId = (integer)tmpSubStr;

                llSetObjectDesc(originalObjectDesc);

                return resultId;

            }

        }

        // no found id.

        timeupCounter++;

        llSleep(0.5);

    }while(timeupCounter < 10);

    llOwnerSay("getPanelId" + ": time up.");

    llSetObjectDesc(originalObjectDesc);

    return -1;

}





init()

{

    //llResetScript();    //reset the historic low memory mark.    //DO NOT DO IT cause script DONT RUN!!

    //llOwnerSay("---init " + llGetObjectName() + " with " + llGetScriptName() + "---");

    llSetTexture("5748decc-f629-461c-9a36-a35a221fe21f", ALL_SIDES);    //Blank Texture

    llOffsetTexture(1.0, 1.0, ALL_SIDES);

    llRotateTexture(0.0, ALL_SIDES);

    llScaleTexture(1.0, 1.0, ALL_SIDES);

    //

    PANEL_ID = getPanelId();

    //llOwnerSay("---id = " + (string)PANEL_ID + ", " + llGetObjectName() + " with " + llGetScriptName() + "---");

    //if(llGetListLength(unicodeTextureList) <= 0)

    //{

    //    generateUnicodeTextureList();

    //}

}



key getTextureUuid(integer utf16Code)

{

    if((utf16Code < 0) || (0xFFFF < utf16Code))

    {

        //out of range.

        //return texture "Blank Texture"

        llSay(DEBUG_CHANNEL, "not include texture for " +(string)utf16Code + "(out of range)");

        return BLANK_TEXTURE;       

    }

    

    // using local-variable. because large-global-variable occurs "Stack-Heap Collision"

    list unicodeTextureList = [];

    integer tmpCode = utf16Code / 0x1000;

    

    //0x0x

    if(tmpCode == 0x0){

        unicodeTextureList = [

        "076bbe11-8311-986c-9d84-d7b9281f2809", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0x1){

        //0x1x

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0x2){

        //0x2x

        unicodeTextureList = [

        "6c0c77b6-79db-fcc5-2648-4b10fbead8e8", "",

        "e9fbf6fc-9b9e-fa19-87a2-b65d184eba13", "",

        "ee7c6253-259c-124f-8f8a-6a36d006bc17", "0c8ed7f3-614c-33c8-ed0e-d9783ca0415f",

        "c9d8e8c7-0164-d117-72f5-bc977e44259c", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0x3){

        //0x3x

        unicodeTextureList = [

        "f05dd50c-92f1-3575-f00c-527bcb9b46c4", "",

        "9c1abffe-b170-17bd-49db-4b2a620eae38", "e9b32e7f-4d36-8f87-fb6c-fe08ea947829",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0x4){

        //0x4x

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "6d47803a-63dd-0a77-6121-8af1509fe608", "410c2ff0-8e7d-33a3-a272-2b2102a3fdde" ];

    }

    else if(tmpCode == 0x5){

        //0x5x

        unicodeTextureList = [

        "26475026-d4d3-ba0b-2cf2-cc7cfc261e47", "c4979f93-c28d-0e85-e2f6-44168b4a5163",

        "3850d8e3-5710-a982-6480-3cfcdc9aa04a", "8c846281-e4f6-3f8e-eb2e-7530a6fcf9be",

        "a96eb8ea-a31e-191c-dbb2-f2df9ce96e4d", "4ba0d2f8-901a-6a9f-c2ca-bc645d4594dd",

        "2e0d8ac5-1bb3-cf66-be11-ea0d1703a837", "80b3ea29-0ae7-9e89-f6f2-daf05ed8b5a2",

        "6502974f-f38a-d2d7-e519-b9b2bf2ab683", "7b97c67e-578f-c9d5-864c-e32cc8e31a53",

        "6a660ec6-66e1-67c0-e4e4-d1be4bda71bc", "19078e30-2df2-a28c-d179-2a08ada6326c",

        "69aa65b5-b1ff-f39f-acd5-68d5e76c539c", "93d5a34b-edaf-fd16-8ec2-e43a3c71476a",

        "c2706129-f10a-a22d-ccc1-8854f72b97b7", "183e1eeb-a4ec-04b6-8bbc-22786b91ebaf" ];

    }

    else if(tmpCode == 0x6){

        //0x6x

        unicodeTextureList = [

        "62c6f23c-e624-8000-261a-35e3a2f96ec1", "9a905213-0aba-b59d-d322-6cc3449a07e4",

        "8e269e54-55d7-1902-24a3-cc9f76794d47", "5cca0353-fe81-ced8-a9ac-2337fdec59bc",

        "49881ca6-30b0-b9e0-57a1-ee2d3f11577f", "4dbf1a74-ffae-1daa-7d4f-319394bfe602",

        "7a6f16cc-1c52-e72f-a462-8a3d5d15fcb3", "3f0b6802-0106-ccbc-bec0-ea8ea09820da",

        "9da9d32c-d973-1f3d-104a-65641a78a4ba", "afc15eab-e42a-de6a-c78c-99f5de5fea82",

        "d2dd4b0d-7560-ec44-579d-9938756f0cb3", "6b6be1f9-2020-fcbd-eed8-99918ec15898",

        "198458aa-6f09-8a35-4e85-0fdfbb4a9ec0", "66a849b7-27c6-a244-9b5b-3c1ac821c54b",

        "853f7712-adcd-c4d2-3850-82543d7ffa50", "269c5acc-1d2c-96b9-0304-5b7662441ab8" ];

    }

    else if(tmpCode == 0x7){

        //0x7x

        unicodeTextureList = [

        "ef013738-c408-2dae-a512-fc9de5947902", "91d31c98-1560-bf9e-7b62-a4e93ac3af88",

        "798754a9-0075-0577-e062-65af8a494cb6", "0d3ead69-f82b-ddb3-d74d-1829ab213fe3",

        "14063115-cfc8-7849-2a77-69a343e6f476", "619c2793-f087-875c-eec6-90d71fd7d418",

        "b7439ff0-f856-e617-87cc-6ddda9b2dcba", "971485a2-e4bd-a56c-212b-b1151b21a125",

        "e38733fa-50ed-f52d-9824-f1709316d1ff", "51b71bef-7666-bef8-0a08-6a50e2239929",

        "261fffc4-9ad7-3385-8ca0-5860f48cc2f3", "5f50f736-4b2e-e912-ae80-6db4252d1ebd",

        "66139dea-753e-fabb-52c6-bfa107b29e2f", "12762919-4d3d-3f16-6165-b5440807ed44",

        "21ec632a-0067-0293-05de-56caabbd95aa", "b00bf885-cd2f-0fe0-2aca-447987afd177" ];

    }

    else if(tmpCode == 0x8){

        //0x8x

        unicodeTextureList = [

        "689a04e4-bb98-9b81-df04-16cec554eb43", "526eb118-7b2a-abea-3828-c5152db78f4d",

        "1e4e6418-ca0b-bd0c-1437-2dedea7b518c", "652dda47-fb86-520a-25af-fd437d330554",

        "fdc4e76c-18a5-2894-32c6-7d061af62572", "2ff4c3af-6336-c981-e6c0-e3aae3460038",

        "f183be69-a91d-5024-3c96-ea4b12cb07bd", "3802a663-edff-730e-1ae0-23e7b6ec5fed",

        "e7eda4a0-11c4-b8a4-74fa-d20f880a566c", "79f91bba-7073-379c-8eac-53fbb06cb26f",

        "d6823eee-2901-ed37-e1f1-b2a9e1c1356b", "16fc3a2c-a223-068b-10ef-c8c85b52d5f7",

        "22ae5233-66de-463b-862b-384870c582e6", "905c276c-1c49-11f3-56ab-05c5597c6281",

        "dfc56ba3-f927-cf1c-f3c4-acf4f55ae3e3", "56ee1d93-8112-6627-aab2-7aaff4bbf5fb" ];

    }

    else if(tmpCode == 0x9){

        //0x9x

        unicodeTextureList = [

        "5ad9d6b5-6be4-156b-e4eb-42c562d498b1", "2d330cd1-beab-5084-bcfe-dacfe1685632",

        "a1ba5b50-0012-479c-a8b9-e31f6857cd61", "47ce3a46-9657-78e4-a445-63a061fca540",

        "2e31a0b5-4b12-a583-1ec6-d46e11a8cbcb", "97944370-1a08-0f93-63af-e0ef4fbf0ea2",

        "c5e18a11-7f93-20f9-c4c0-9bfebdf0b9de", "f1425639-26eb-ee95-059d-081985653aee",

        "b2abb2bf-577d-87a4-8bfd-c6c82c153694", "03eefe4f-8f4b-5445-dd8c-ce6e10331363",

        "1f836cd8-dfcb-407f-d39a-48ea8c5b5fe4", "ae0b5721-0da9-d345-98ce-064e8c8b0aab",

        "0e05c2d5-031e-a774-f138-1d39f1bdfbaf", "77538262-b6fc-c0ff-247b-d45c871d4c31",

        "b5a0805d-9293-7b54-f4eb-9ab19fc1c258", "137a0451-e9de-2484-8939-c767a84b24bf" ];

    }

    else if(tmpCode == 0xA){

        //0xax

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0xB){

        //0xbx

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0xC){

        //0xcx

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0xD){

        //0xdx

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0xE){

        //0xex

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "",

        "", "" ];

    }

    else if(tmpCode == 0xF){

        //0xfx

        unicodeTextureList = [

        "", "",

        "", "",

        "", "",

        "", "",

        "", "ede8dac7-e8d4-b429-b398-ae49a1719724",

        "421d6279-9472-39e0-b485-5ec576783100", "",

        "", "",

        "", "4ad3c8f2-0f02-a848-f498-534fd42160b8" ];

    }

    

    key resultKey;

    resultKey = llList2Key(unicodeTextureList, ((utf16Code / 0x0100) % 0x10));

    if((resultKey == "") || (resultKey == NULL_KEY))

    {

        if(isDebugMode == TRUE)

        {

            llSay(DEBUG_CHANNEL, "not include texture for " +(string)utf16Code);

        }

        return (key)"5748decc-f629-461c-9a36-a35a221fe21f";

    }

    return resultKey;

}



vector utf16Code2pos(integer code)

{

    integer x;

    integer y;

    vector pos;

    //

    code = code & 0xFF;

    //

    x = code % xmax;

    if(x > xmax || x < 0)

    {

        x = 0;

    }

    pos.x = (1.0 / xmax) * ((xmax / 2) - x - 0.5);

    pos.x *= (-1);

    //

    y = code / xmax;    //xmax is. NOT ymax.

    if(y > ymax || y < 0)

    {

        y = 0;

    }

    pos.y = (1.0 / ymax) * ((ymax / 2) - y - 0.5);

    //

    return pos;

}



integer inPrimPos2face(integer inPrimPos)

{

    //for prism prim

    if(inPrimPos == INPRIM_LEFT_LEFT   ){ return 3; }        //left-left

    if(inPrimPos == INPRIM_LEFT_CENTER ){ return 7; }        //left-center

    if(inPrimPos == INPRIM_CENTER      ){ return 4; }        //center

    if(inPrimPos == INPRIM_RIGHT_CENTER){ return 6; }        //right-center

    if(inPrimPos == INPRIM_RIGHT_RIGHT ){ return 1; }        //right-right

    return -1;

}



float inPrimPos2angle(integer inPrimPos)

{

    //for prism prim

    return 0.0;

}



// prism-center face is shrinked and shifted.

vector inPrimPos2prismOffset(integer inPrimPos)

{

    if(inPrimPos == INPRIM_LEFT_LEFT   ){ return <0.040, 0.0, 0.0>; }        //left-left// <-0.255989, 0.0, 0.0>; }        //left-left

    if(inPrimPos == INPRIM_LEFT_CENTER ){ return <-0.005, 0.0, 0.0>; }        //left-center

    if(inPrimPos == INPRIM_CENTER      ){ return <0.615, 0.0, 0.0>; }        //center

    if(inPrimPos == INPRIM_RIGHT_CENTER){ return <-0.004, 0.0, 0.0>; }        //right-center

    if(inPrimPos == INPRIM_RIGHT_RIGHT ){ return <-0.05, 0.0, 0.0>; }        //right-right// <-0.740013, 0.0, 0.0>; }        //right-right

    return ZERO_VECTOR;

}



// prism-center face is shrinked and shifted.

vector inPrimPos2prismScale(integer inPrimPos)

{

    if(inPrimPos == INPRIM_LEFT_LEFT   ){ return <2.48, 1.0, 0.0>; }        //left-left

    if(inPrimPos == INPRIM_LEFT_CENTER ){ return <1.0, 1.0, 0.0>; }        //left-center

    if(inPrimPos == INPRIM_CENTER      ){ return <-14.75, 1.0, 0.0>; }        //center

    if(inPrimPos == INPRIM_RIGHT_CENTER){ return <1.0, 1.0, 0.0>; }        //right-center

    if(inPrimPos == INPRIM_RIGHT_RIGHT ){ return <2.48, 1.0, 0.0>; }        //right-right

    return ZERO_VECTOR;

}



vector normalizeTextureOffset(vector offset)

{

    //llOwnerSay("normalize input= " + (string)offset);

    while(offset.x >  1.0){ offset.x = (2.0 - offset.x) * (-1);}

    while(offset.x < -1.0){ offset.x = (1.0 + offset.x);}

    while(offset.y >  1.0){ offset.y = (2.0 - offset.y) * (-1);}

    while(offset.y < -1.0){ offset.x = (1.0 + offset.y);}

    //llOwnerSay("normalize output=" + (string)offset);

    return offset;

}



vector setCharactor(integer utf16Code, integer inPrimPos)

{

    key textureUuid;

    //range check.

    if(utf16Code < 0)

    {

        llSay(DEBUG_CHANNEL, (string)utf16Code + "is code range error");

        return <-1.0, -1.0, -1.0>;

    }

    if(PRIM_PER_CHARACTOR < inPrimPos)

    {

        llSay(DEBUG_CHANNEL, (string)inPrimPos + "is prim range error.(only " + (string)PRIM_PER_CHARACTOR + "charactor can set.");

        return <-1.0, -1.0, -1.0>;

    }

    //

    //get texture infomation.

    //

    integer faceNum = inPrimPos2face(inPrimPos);

    //hide texture while change.

    if(isDebugMode == FALSE)

    {

        llSetAlpha(0.0, faceNum);

    }

    //get texture uuid.

    textureUuid = getTextureUuid(utf16Code);

    llSetTexture(textureUuid, faceNum);

    //return IF cannot mapping. 

    if(textureUuid == BLANK_TEXTURE)

    {

        //llSetAlpha(0.0, faceNum);     //still transparent.

        return FAIL_MAPPING_VECTOR;

    }

    //

    //set texture to face.

    //

    //shift texture.

    vector pos = utf16Code2pos(utf16Code);

    pos = pos + inPrimPos2prismOffset(inPrimPos);

    pos = normalizeTextureOffset(pos);

    llOffsetTexture(pos.x, pos.y, faceNum);

    //llOwnerSay("setCaractor " + (string)pos);

    //rotete texture

    float angle = inPrimPos2angle(inPrimPos);

    llRotateTexture(angle, faceNum);

    //streatch texture.

    vector scale = <(1.0 / xmax), (1.0 / ymax), 0.0>;

    vector prismScale = inPrimPos2prismScale(inPrimPos);

    scale.x = scale.x * prismScale.x;

    scale.y = scale.y * prismScale.y;

    llScaleTexture(scale.x, scale.y, faceNum);      // kakudai

    if(isDebugMode == FALSE)

    {

        llSetAlpha(1.0, faceNum);

    }

    //for debug.

    //llOwnerSay("offset=" + (string)pos + ", scale=" + (string)scale + ", prismOffset=" + (string)inPrimPos2prismOffset(inPrimPos));

    return pos;

}



default

{

    state_entry()

    {

        init();

    }

    on_rez(integer start_param)

    {

        init();

    }

    

    link_message(integer sender_num, integer charactorUtf16Code, string charactorPosStr, key id)

    {

        integer charactorPos;

        charactorPos = (integer)charactorPosStr;

        if((PANEL_ID * PRIM_PER_CHARACTOR <= charactorPos) &&

        (charactorPos < (PANEL_ID + 1) * PRIM_PER_CHARACTOR) )

        {

            //llSetText((string)charactorUtf16Code, <1,1,1>, 1.0);

            setCharactor(charactorUtf16Code, (charactorPos % PRIM_PER_CHARACTOR));

        }

    }

    

    //touch_start(integer total_number)

    //{

    //    llSay(0, "reset.");

    //    init();

    //}

}